All commands

Moves the turtle forward n steps (max 32767). The first decimal is kept.

FD 100

Moves the turtle back n steps.

BK 50

Turns right (clockwise) by n degrees. n between -360 and 360.

RT 90

Turns left by n degrees. n between -360 and 360.

LT 45

Sends the turtle back to the center, heading 0, without changing the pen.

HOME

Outputs the current position [x y].

PRINT POS
  -> 0 0

Moves the turtle through a list of points (even number of coordinates). Keeps the heading; draws if the pen is down.

SETPOS [ 50 80 ]

Moves the turtle to the point (x, y). Keeps the heading; draws if the pen is down.

SETXY 100 50

Outputs the turtle's x coordinate.

PRINT XCOR
  -> 0

Outputs the turtle's y coordinate.

PRINT YCOR
  -> 0

Outputs the current heading, 0 to 359.9 (compass, North = 0 = up).

PRINT HEADING
  -> 0

Sets the absolute heading (compass). n between -360 and 360.

SETHEADING 90

Outputs the heading (0-360) to face the point [x y] from the turtle's position.

SETHEADING TOWARDS [ 100 0 ]

Outputs the distance from the turtle to the point [x y].

PRINT DISTANCE [ 30 40 ]
  -> 50

Draws a circle of radius r centred on the turtle: the turtle stays in place (at the centre), heading unchanged.

CIRCLE 50

Draws an arc of radius r centred on the turtle, between compass headings cap1 and cap2 (0 = up, clockwise). The turtle does not move.

ARC 50 0 90

Shows the turtle.

SHOWTURTLE

Hides the turtle (drawing is faster).

HIDETURTLE

Outputs TRUE if the turtle is shown.

PRINT SHOWN?
  -> VRAI

Selects the active turtle's shape: 0 = triangle (default), 1 = detailed turtle, 2 = car, 3 to 255 = shapes defined with DEFSPRITE. Each turtle keeps its own shape.

SPRITE 1

Defines the 16×16 shape number n (3 to 255), then selectable with SPRITE n. The list gives up to 16 rows of 16 characters: '.' = empty, any other character ('X' for instance) = filled. The shape is drawn in the pen color and rotates with the heading. Kept by CLEARSCREEN, cleared by RESET.

DEFSPRITE 3 [ .XXXX. XXXXXX XXXXXX .XXXX. ]

Clears the screen: resets the graphics and the turtle state (center, heading 0, pen down cyan, blue background, FENCE field) and keeps a single turtle, number 0. INIT is an alias (XLogo name).

CLEARSCREEN

Clears the field without changing the turtle or pen state.

CLEAN

Outputs the graphics background color code.

PRINT BACKGROUND
  -> 4

Sets the graphics background color: palette code 0-15, or [ red green blue ] (3 values 0-255).

SETBACKGROUND 2
SETBACKGROUND [ 30 30 60 ]

Sets the graphics screen border color: code 0-15, or [ red green blue ] (0-255).

SETBORDER 7
SETBORDER [ 80 80 80 ]

Outputs the [horizontal vertical] scales, in percent.

PRINT SCALE
  -> 100 100

Sets the horizontal and vertical scales (2 numbers 0 to 200, in %). Stretches the turtle's drawing.

SETSCALE [ 50 100 ]

Bounded field: the turtle refuses to leave the screen (default mode).

FENCE

Wrapped field: the turtle reappears on the opposite edge (torus).

WRAP

Window field: space extends beyond the visible screen.

WINDOW

Lights a list of points (pen color) without moving the turtle.

DOT [ 0 0 50 50 ]

Draws instr in a hidden buffer, then shows it all at once (double buffering). Prevents flicker in animations that CLEAN then redraw every frame. Use it around the drawing of one frame inside a loop.

SCENE [ CLEAN SQUARE ]

Selects the active turtle n (created if needed, numbers 0 to 1023). Subsequent commands (FD, RT, SETPC...) act on it. Background, scale and field mode stay shared by all turtles.

SETTURTLE 1

Outputs the active turtle number.

PRINT TURTLE
  -> 0

Outputs the number of existing turtles.

PRINT TURTLES
  -> 1

Runs list on turtle n (or on each turtle of a list of numbers) then returns to the previously active turtle.

ASK 1 [ FD 50 ]
ASK [ 0 1 ] [ RT 90 ]

Removes all turtles except the first one (#0) and selects it.

CLEARTURTLES

Outputs TRUE if the two turtles in the list [ a b ] exist, are visible and overlap (bounding boxes matching each sprite's size). Otherwise FALSE.

PRINT COLLIDE? [ 0 1 ]
  -> FAUX

Automatically moves turtle id toward point (x,y), by `speed` Logo steps per frame, in parallel with the program. mode is a word: "ONCE (go to target then stop), "LOOP (jump back to start and repeat), "PINGPONG (continuous back and forth). Frame rate is set with CADENCE. A manual command (FD, SETXY...) on the turtle stops its animation.

ANIMATE 0 200 100 5 "PINGPONG

Stops the animation (ANIMATE) of turtle id. In parentheses with no argument, (STOPANIMATE) stops all animations. Ctrl+C also stops animations.

STOPANIMATE 1
( STOPANIMATE )

Sets the animation engine's frame rate to n frames per second (1 to 240, default 30). An ANIMATE's speed (steps per frame) is independent of the frame rate.

SETFPS 60

Pen down: the turtle draws as it moves.

PENDOWN

Pen up: the turtle no longer draws.

PENUP

Outputs TRUE if the pen is down.

PRINT PENDOWN?
  -> VRAI

Outputs the pen color code.

PRINT PENCOLOR
  -> 6

Sets the pen color: either a palette code 0-15 (a negative code erases), or [ red green blue ] with 3 values 0-255 for a free color.

SETPENCOLOR 1
SETPENCOLOR [ 255 128 0 ]

Sets the pen width in pixels (minimum 1; default 2).

SETPENSIZE 4

Fills the enclosed area that contains the turtle. Color: the one set by SETFLOODCOLOR if any, otherwise the pen color.

FILL

Sets the flood color used by FILL, separate from the pen color: palette code 0-15, or [ red green blue ] (3 values 0-255). Until it is set, FILL uses the pen color. (FMSLogo compatibility: FILL is based on this color.)

SETFLOODCOLOR 1
SETFLOODCOLOR [ 255 128 0 ]

Outputs the flood color code (SETFLOODCOLOR). If it has not been set, outputs the pen color (the effective FILL color).

PRINT FLOODCOLOR
  -> 6

Writes obj in the graphics field at the turtle's position (pen color).

LABEL "BONJOUR

Outputs TRUE if obj1 and obj2 are equal. Infix operator: =. Word comparison ignores letter case (EQUAL? "a "A is TRUE); when case matters, compare codes: EQUAL? ASCII :c1 ASCII :c2.

PRINT EQUAL? 2 2
  -> VRAI

Outputs TRUE if obj is the empty word or empty list.

PRINT EMPTY? [ ]
  -> VRAI

Outputs TRUE if obj is a list.

PRINT LIST? [ A B ]
  -> VRAI

Outputs TRUE if obj is a word.

PRINT WORD? "BONJOUR
  -> VRAI

Outputs TRUE if obj is a number.

PRINT NUMBER? 42
  -> VRAI

Outputs TRUE if obj is a member of list.

PRINT MEMBER? "A [ A B C ]
  -> VRAI

Outputs the number of members of a list, characters of a word, or cells of an array.

PRINT COUNT [ A B C ]
  -> 3

Outputs the ASCII code of the first character of word (empty word -> 0).

PRINT ASCII "A
  -> 65

Outputs the character of code n (modulo 256; 0 -> empty word).

PRINT CHAR 65
  -> A

Outputs the first member of a list (or first character of a word).

PRINT FIRST [ A B C ]
  -> A

Outputs the last member of a list (or last character of a word).

PRINT LAST [ A B C ]
  -> C

Outputs obj without its first element.

PRINT BUTFIRST [ A B C ]
  -> B C

Outputs obj without its last element.

PRINT BUTLAST [ A B C ]
  -> A B

Outputs the nth member of a list, the nth character of a word, or cell n of an array (n integer; for an array the origin is taken into account).

PRINT ITEM 2 [ A B C ]
  -> B
PRINT ITEM 2 "CHAT
  -> H

Outputs a randomly chosen member of a list (or character of a word). (FMSLogo compatibility.)

PRINT PICK [ PILE FACE ]
  -> FACE

Concatenates word1 and word2 into a single word.

PRINT WORD "BON "JOUR
  -> BONJOUR

Builds a list from obj1 and obj2 (flattens lists).

PRINT SENTENCE "A "B
  -> A B

Builds the list [obj1 obj2].

PRINT LIST "A "B
  -> A B

Adds obj at the front of list.

PRINT FPUT "A [ B C ]
  -> A B C

Adds obj at the end of list.

PRINT LPUT "C [ A B ]
  -> A B C

Outputs the list (or word) with its elements in reverse order.

PRINT REVERSE [ A B C ]
  -> C B A

Outputs the list sorted: numbers by increasing value, otherwise alphabetically. Stable sort.

PRINT SORT [ 3 1 2 ]
  -> 1 2 3
PRINT SORT [ POMME CERISE BANANE ]
  -> BANANE CERISE POMME

Outputs the word in upper case.

PRINT UPPERCASE "bonjour
  -> BONJOUR

Outputs the word in lower case.

PRINT LOWERCASE "BONJOUR
  -> bonjour

Outputs the portion of thing2 (word or list) from the first occurrence of thing1 to the end, or empty if thing1 is absent. On a word, thing1 is a single character.

PRINT MEMBER "C "ABCDE
  -> CDE
PRINT MEMBER "B [ A B C ]
  -> B C

Outputs TRUE if thing1 is a substring of the word thing2 (case-insensitive). FALSE if either one is a list.

PRINT SUBSTRING? "bc "abc
  -> VRAI

Outputs TRUE if word1 comes before word2 in alphabetical order (case-insensitive).

PRINT BEFORE? "abc "abd
  -> VRAI

Outputs the rank (1-based) of the first occurrence of thing in chaine, or 0 if absent. In a word, thing can be a substring; in a list, an element. Case-insensitive. gologo extension.

PRINT POSITION "n "bonjour
  -> 3
PRINT POSITION "B [ A B C ]
  -> 2

Splits word on the separator and outputs the list of pieces (empty pieces are kept). The separator may be a single character or a whole string. gologo extension.

PRINT SPLIT "1-2-3 "-
  -> 1 2 3
PRINT SPLIT "a::b::c "::
  -> a b c

Outputs string with every occurrence of the substring old replaced by new. In parentheses, (SUBSTITUTE old new string n) replaces at most n. An empty old is an error. gologo extension.

PRINT SUBSTITUTE "an "AN "banane
  -> bANANe
PRINT ( SUBSTITUTE "a "o "ananas 1 )
  -> onanas

Outputs word without leading and trailing blanks (spaces, tabs). Useful on a line read from input. gologo extension.

PRINT TRIM "bonjour
  -> bonjour

Outputs word without leading blanks. gologo extension.

PRINT LTRIM "bonjour
  -> bonjour

Outputs word without trailing blanks. gologo extension.

PRINT RTRIM "bonjour
  -> bonjour

Outputs elements (list or word) without all members equal to thing. On a word, thing is a single character.

PRINT REMOVE "A [ A B A C ]
  -> B C

Outputs sequence (word or list) without length elements starting at start (1-based). Removes by position (unlike REMOVE, which removes by value). gologo extension.

PRINT DELETE "bonjour 2 3
  -> bour
PRINT DELETE [ A B C D ] 2 2
  -> A D

Outputs a copy of elements with duplicates removed: if a member appears several times, the rightmost one is kept.

PRINT REMDUP [ A B C C B ]
  -> A C B

Outputs sequence (word or list) with item number n replaced by arg (1-based). Non-destructive (outputs a new value). From XLogo.

PRINT REPLACE [ A B C ] 2 8
  -> A 8 C
PRINT REPLACE "chat 1 "r
  -> rhat

Outputs sequence (word or list) with arg inserted at position n (n from 1 to length+1). From XLogo.

PRINT INSERTITEM [ A B C ] 2 8
  -> A 8 B C
PRINT INSERTITEM "cat 2 "h
  -> chat

Outputs the subsequence from start to end inclusive (1-based, like ITEM); the type follows the input (word or list). (SLICE sequence start) goes to the end. Out-of-range bounds are clamped. gologo extension.

PRINT SLICE "bonjour 2 4
  -> onj
PRINT ( SLICE "bonjour 4 )
  -> jour
PRINT SLICE [ A B C D ] 2 3
  -> B C

Outputs an array of size cells, each initially the empty list (not 0: initialise the cells before using them as counters or flags). (ARRAY size origin) sets the first cell's index (1 by default). An array is mutable and shared by reference. From FMSLogo.

SHOW ARRAY 3
  -> { }
MAKE "T ( ARRAY 3 0 )

Outputs a multi-dimensional array: one dimension per size in the list (positive sizes). (MDARRAY sizelist origin) sets the origin. From FMSLogo.

SHOW MDARRAY [ 2 2 ]
  -> {{ } { }}

Outputs an array with the same elements as the list. (LISTTOARRAY list origin) sets the origin. From FMSLogo.

SHOW LISTTOARRAY [ 1 2 3 ]
  -> {1 2 3}

Outputs the list of the array's cells (first cell first, whatever the origin). Handy to process an array with MAP/FILTER. From FMSLogo.

SHOW ARRAYTOLIST LISTTOARRAY [ 1 2 3 ]
  -> [1 2 3]

Outputs the cell of a multi-dimensional array, selected by a list of indices. From FMSLogo.

PRINT MDITEM [ 1 ] LISTTOARRAY [ 7 8 9 ]
  -> 7

Replaces cell index of the array with value (mutates the array in place). Refuses to create a cycle (value must not contain the array). From FMSLogo.

MAKE "T ARRAY 3 SETITEM 2 :T 9 PRINT ITEM 2 :T
  -> 9

Replaces a cell of a multi-dimensional array (selected by a list of indices) with value. Refuses cycles. From FMSLogo.

MAKE "T MDARRAY [ 2 2 ] MDSETITEM [ 1 2 ] :T 5 PRINT MDITEM [ 1 2 ] :T
  -> 5

Outputs TRUE if thing is an array.

PRINT ARRAY? ARRAY 3
  -> VRAI

Outputs a DEEP copy of the array (recursive on sub-arrays, sharing preserved), so the copy can be modified without touching the original. gologo extension.

MAKE "T ARRAY 3 MAKE "C COPYARRAY :T PRINT ARRAY? :C
  -> VRAI

Sorts the array's slots in place (numbers by increasing value, otherwise alphabetically). Modifies the array, like SETITEM; stable sort. Faster than SORT on large data.

MAKE "T LISTTOARRAY [ 3 1 2 ] SORTARRAY :T SHOW :T
  -> {1 2 3}

Adds value to the front of the list named nomvar (stack). Pop it with POP. From FMSLogo.

MAKE "P [ ] PUSH "P 1 PUSH "P 2 SHOW :P
  -> [2 1]

Removes and outputs the front element of the list named nomvar (stack, last in first out). From FMSLogo.

MAKE "P [ ] PUSH "P 1 PUSH "P 2 PRINT POP "P
  -> 2

Adds value to the back of the list named nomvar (queue). Dequeue it with DEQUEUE. From FMSLogo.

MAKE "F [ ] QUEUE "F 1 QUEUE "F 2 SHOW :F
  -> [1 2]

Removes and outputs the oldest element (at the front) of the list named nomvar (queue, first in first out). From FMSLogo.

MAKE "F [ ] QUEUE "F 1 QUEUE "F 2 PRINT DEQUEUE "F
  -> 1

Outputs the word TRUE.

PRINT TRUE
  -> VRAI

Outputs the word FALSE.

PRINT FALSE
  -> FAUX

Logical AND: TRUE if both predicates are TRUE. In parentheses, accepts several: (AND a b c).

PRINT AND TRUE FALSE
  -> FAUX
PRINT ( AND TRUE TRUE TRUE )
  -> VRAI

Logical OR: TRUE if at least one predicate is TRUE. In parentheses: (OR a b c).

PRINT OR TRUE FALSE
  -> VRAI
PRINT ( OR FALSE FALSE TRUE )
  -> VRAI

Logical negation.

PRINT NOT TRUE
  -> FAUX

Outputs TRUE if n1 < n2. Infix operator: <.

PRINT LESS? 3 5
  -> VRAI

Outputs TRUE if n1 > n2. Infix operator: >.

PRINT GREATER? 5 3
  -> VRAI

Sum n1 + n2. Infix operator: +.

PRINT SUM 3 4
  -> 7

Difference n1 - n2. Infix operator: -.

PRINT DIFFERENCE 10 4
  -> 6

Product n1 * n2. Infix operator: *.

PRINT PRODUCT 6 7
  -> 42

Quotient n1 / n2 (n2 not 0). Infix operator: /.

PRINT QUOTIENT 20 4
  -> 5

Integer quotient of n1 by n2 (n2 not 0).

PRINT INTQUOTIENT 17 5
  -> 3

Remainder of the integer division of n1 by n2 (n2 not 0).

PRINT REMAINDER 17 5
  -> 2

Remainder of n1 divided by n2, with the sign of n2 (differs from REMAINDER for negatives).

PRINT MODULO -17 5
  -> 3

Outputs n1 raised to the power n2.

PRINT POWER 2 10
  -> 1024

Square root of n (n >= 0).

PRINT SQRT 16
  -> 4

Absolute value of n.

PRINT ABS -7
  -> 7

Outputs the negation of n (-n).

PRINT MINUS 5
  -> -5

Integer part of n (rounded down: INT -1.5 = -2).

PRINT INT 3.7
  -> 3

Outputs the nearest integer to n.

PRINT ROUND 3.6
  -> 4

Outputs the integer part of n (truncated toward zero).

PRINT TRUNCATE 3.9
  -> 3

Outputs a random integer between 0 and n-1 (n >= 1). In parentheses, (RANDOM start end) picks between start and end inclusive.

PRINT RANDOM 6
  -> 5
PRINT ( RANDOM 1 6 )
  -> 6

Sine of n (n in degrees).

PRINT SIN 30
  -> 0.5

Cosine of n (n in degrees).

PRINT COS 60
  -> 0.5

Tangent of n (n in degrees).

PRINT TAN 45
  -> 1

Arctangent of n, in degrees.

PRINT ARCTAN 1
  -> 45

Exponential: e to the power n.

PRINT EXP 1
  -> 2.7182818285

Natural logarithm of n (n > 0).

PRINT LN 1
  -> 0

Base-10 logarithm of n (n > 0).

PRINT LOG10 100
  -> 2

Outputs the constant pi (3.14159...).

PRINT PI
  -> 3.141592653589793

Bitwise exclusive-or of two non-negative integers (XOR 6 3 = 5).

PRINT XOR 6 3
  -> 5

Writes the integer n in the given base (2 to 36), in upper case: TOBASE 255 16 gives FF. See HEX and BIN for the common cases.

PRINT TOBASE 255 16
  -> FF

Reads the word as a number written in the given base (2 to 36) and outputs its value: FROMBASE "FF 16 gives 255.

PRINT FROMBASE "FF 16
  -> 255

Shows the integer n in hexadecimal (base 16). Shorthand for TOBASE n 16.

PRINT HEX 255
  -> FF

Shows the integer n in binary (base 2). Shorthand for TOBASE n 2.

PRINT BIN 10
  -> 1010

Expands and simplifies a literal expression (with variables), given between brackets. Multiplication may stay implicit (3x, 2(x+1)) and case is ignored. Division by an expression simplifies the fraction when it comes out even, otherwise it gives the quotient and remainder (e.g. (x^2+1)/(x-1) gives x + 1 + 2/(x-1)). With a single variable you can also add and simplify fractions. Example: EXPAND [ (3x+5y)(3x-5y) ] outputs 9x^2 - 25y^2. gologo extension.

PRINT EXPAND [ (3x+5y)(3x-5y) ]
  -> 9X^2 - 25Y^2
PRINT EXPAND [ (x+2)^2 ]
  -> X^2 + 4X + 4

Factors an expression given between brackets: common factor and remarkable identities (a^2-b^2, a^2±2ab+b^2); with a single variable, factoring by all rational roots, whatever the degree. Examples: FACTOR [ 9x^2 - 25y^2 ] outputs (3x + 5y)(3x - 5y), FACTOR [ x^3 - 6x^2 + 11x - 6 ] outputs (x - 1)(x - 2)(x - 3). What does not factor with these rules is returned unchanged. gologo extension.

PRINT FACTOR [ 9x^2 - 25y^2 ]
  -> (3X + 5Y)(3X - 5Y)
PRINT FACTOR [ x^2 + 4x + 4 ]
  -> (X + 2)^2

Solves a one-unknown equation, of the first or second degree, given between brackets with an = sign. Outputs the solution(s) (or "no real solution"). Example: SOLVE [ x^2 - 5x + 6 = 0 ] outputs x = 2 or x = 3. gologo extension.

PRINT SOLVE [ 2x + 3 = 7 ]
  -> X = 2
PRINT SOLVE [ x^2 - 5x + 6 = 0 ]
  -> X = 2 or X = 3

Replaces variables with values in an expression (between brackets). The values are given as variable/number pairs, also between brackets. Evaluation may be partial (unset variables remain). Example: EVALUATE [ x^2 + 1 ] [ x 3 ] outputs 10. gologo extension.

PRINT EVALUATE [ x^2 + 1 ] [ x 3 ]
  -> 10
PRINT EVALUATE [ x^2 + y ] [ x 2 y 5 ]
  -> 9

Gives the name word to object obj (variable). Read its value with :word or THING.

MAKE "AGE 10
MAKE "NOM [ JEAN DUPONT ]

Outputs the thing (value) named by word. :word is short for THING "word.

MAKE "AGE 10 PRINT THING "AGE
  -> 10

Outputs TRUE if word names a thing (defined variable).

PRINT NAME? "AGE
  -> FAUX

Declares one or more variables local to the current procedure: MAKE then only affects the local copy, not the global of the same name.

LOCAL "COMPTE
LOCAL [ X Y ]

Defines a procedure named word, with optional parameters. End with END.

TO CARRE REPEAT 4 [ FD 50 RT 90 ] END

Ends a procedure definition (TO ... END).

TO CARRE FD 50 END

Ends the current procedure, outputting obj (makes it an operation).

OUTPUT :N * 2

Immediately ends the current procedure.

IF :N = 0 [ STOP ]

Outputs TRUE if word is the name of a user procedure.

PRINT PROCEDURE? "CARRE
  -> FAUX

Outputs TRUE if word is the name of a primitive.

PRINT PRIMITIVE? "AVANCE
  -> VRAI

Opens the full-screen editor (and stops any running animations). EDIT alone reopens the buffer; EDIT "NAME or EDIT [ A B ] edits procedures; EDIT [ ] starts empty. Ctrl+S saves, Ctrl+X quits without saving.

EDIT "CARRE

Defines procedure name from data (procedures as data, advanced Logo style). Two accepted forms: UCBLogo-style nested, DEFINE "name [ [inputs] [body] ] ; or XLogo-style 3-argument, DEFINE "name [inputs] [body]. Inverse of TEXT.

DEFINE "CARRE [ [ ] [ REPEAT 4 [ FD 50 RT 90 ] ] ]
DEFINE "POLY [ NB LG ] [ REPEAT :NB [ FD :LG RT 360 / :NB ] ]

Outputs the definition of procedure name as a list [ [inputs] [body] ]. Inverse of DEFINE.

TO CARRE REPEAT 4 [ FD 50 RT 90 ] END SHOW TEXT "CARRE
  -> CARRE DEFINED [[] [REPEAT 4 [FD 50 RT 90]]]

Conditional: runs list if pred is TRUE, otherwise does nothing. For an else branch, see IFELSE.

IF 2 > 1 [ PRINT "OUI ]
  -> OUI
IF :N = 0 [ PRINT "ZERO ]

Two-branch conditional: runs list1 if pred is TRUE, otherwise runs list2.

IFELSE :N = 0 [ PRINT "ZERO ] [ PRINT "AUTRE ]

Runs list n times (n between 0 and 65535).

REPEAT 4 [ FD 50 RT 90 ]
REPEAT 36 [ FD 20 RT 10 ]

Outputs the current iteration number of REPEAT (1 to n), or -1 outside a loop.

REPEAT 3 [ PRINT REPCOUNT ]
  -> 1 2 3

Runs instr while cond evaluates to TRUE (while loop).

WHILE [ :N > 0 ] [ FD 10 MAKE "N :N - 1 ]

For loop: var goes from start to end (by step, default 1); runs instr each time.

FOR [ I 1 4 ] [ FD 50 RT 90 ]

Runs list; outputs its result if it is an operation. Building block for control structures.

RUN [ FD 50 ]

Runs list like RUN, but wraps the result: outputs [value] if it was an operation, [ ] (empty list) if it was a command. Lets you test whether anything was output.

SHOW RUNRESULT [ SUM 2 3 ]
  -> [5]
SHOW RUNRESULT [ FD 50 ]
  -> []

Full stop: return to top level.

TOPLEVEL

Pauses for n sixtieths of a second (WAIT 60 = 1 second). Interruptible with Ctrl+C.

WAIT 30

After confirmation (Y/N), resets everything to the startup state: erases procedures and variables, resets the turtle and the screen.

RESET

Runs instr for each member of a list (or character of a word). Two forms: our form FOREACH list [instr] with the current item in :? ; or the XLogo form FOREACH "var list-or-word [instr] with a named variable (:var).

FOREACH [ 1 2 3 ] [ PRINT :? ]
  -> 1 2 3
FOREACH "I [ 1 2 3 ] [ PRINT :I ]
  -> 1 2 3

Outputs the list of the template's results applied to each member (:? = member).

PRINT MAP [ 1 2 3 ] [ :? * :? ]
  -> 1 4 9

Outputs the members of list for which the predicate (:?) is TRUE.

PRINT FILTER [ 1 2 3 4 ] [ :? > 2 ]
  -> 3 4

Folds the list into one value: :?1 = accumulator, :?2 = current member.

PRINT REDUCE [ 1 2 3 4 ] [ :?1 + :?2 ]
  -> 10

Runs instr; catches a THROW with the same tag. Tag ERROR also catches runtime errors.

CATCH "FIN [ THROW "FIN ]

Stops execution and jumps to the CATCH with the same tag.

CATCH "FIN [ THROW "FIN ]

Remembers a predicate's result, for IFTRUE / IFFALSE.

TEST 2 > 1 IFTRUE [ PRINT "OUI ]
  -> OUI

Runs instr if the last TEST was TRUE.

TEST 2 > 1 IFTRUE [ PRINT "OUI ]
  -> OUI

Runs instr if the last TEST was FALSE.

TEST 1 > 2 IFFALSE [ PRINT "NON ]
  -> NON

Gives object obj the property prop = value (property lists, advanced Logo style). Replaces it if the property already exists.

PPROP "TINTIN "AGE 17

Outputs the value of property prop of object obj, or the empty list [ ] if it does not exist.

PPROP "TINTIN "AGE 17 PRINT GPROP "TINTIN "AGE
  -> 17

Removes property prop from object obj.

REMPROP "TINTIN "AGE

Outputs the property list of obj: [ prop1 value1 prop2 value2 ... ], or [ ] if obj has no property.

PPROP "TINTIN "AGE 17 SHOW PLIST "TINTIN
  -> [AGE 17]

Prints obj in the text area, then starts a new line. In parentheses, prints several objects separated by a space: (PRINT a b c).

PRINT 5 + 7
  -> 12
PRINT [ BONJOUR LE MONDE ]
  -> BONJOUR LE MONDE
( PRINT "VALEUR 42 )
  -> VALEUR 42

Prints obj without a new line. In parentheses: (TYPE a b c).

TYPE "BONJOUR
  -> BONJOUR
( TYPE "A "B )
  -> A B

Like PRINT, but keeps the brackets around lists: SHOW [ A B ] prints [A B]. Variadic in parentheses.

SHOW [ A B C ]
  -> [A B C]

Clears the text area.

CLEARTEXT

Sets the number of visible text lines (1-25). SETTEXTLINES 25 = full text (hides graphics); n < 25 = mixed screen (graphics + n text lines).

SETTEXTLINES 25
SETTEXTLINES 5

Places the text cursor: column col (0-79), line lig (0-24). The next PRINT/TYPE writes there.

SETCURSOR [ 10 5 ]
CLEARTEXT SETCURSOR [ 0 24 ] TYPE "BAS
  -> BAS

Sets the text color: code 0-15, or [ red green blue ] (0-255).

SETTEXTCOLOR 3
SETTEXTCOLOR [ 255 200 0 ]

Sets the text background color: code 0-15, or [ red green blue ] (0-255).

SETTEXTBACKGROUND 4
SETTEXTBACKGROUND [ 20 20 20 ]

Waits for a keystroke and outputs the typed character (a one-character word). Enter -> carriage return.

MAKE "C READCHAR

Waits for a line of input (until Enter) and outputs it as a list of words.

MAKE "L READLIST

Waits for a line of input (until Enter) and outputs it as a single word.

MAKE "L READWORD

Outputs TRUE if a key is available, without waiting (for READCHAR).

IF KEY? [ PRINT "OUI ]

Displays title (a question) then reads keyboard input and stores it in variable word: a word for a single word, a list for several. (XLogo style, here in text mode.)

READ [ HOW OLD ARE YOU ] "AGE

Outputs the mouse position [x y] if the pointer is in the field, otherwise the empty list.

PRINT MOUSEPOS

Outputs TRUE if a mouse button is pressed.

IF MOUSEDOWN? [ PRINT "CLIC ]

Outputs the direction of joystick n (0-8): 0 = centered, 1 = up, then clockwise (3 = right, 5 = down, 7 = left, plus diagonals). Emulated with the arrow keys (joystick 0).

IF ( JOYSTICK 0 ) = 1 [ FD 10 ]

Outputs TRUE if joystick n's fire button is pressed. Emulated with the space bar (joystick 0).

IF BUTTON? 0 [ PRINT "FEU ]

Plays a single note or a list of notes one after another. Notes: DO RE MI FA SO(L) LA SI, and PA for a rest. Sharp: # (or <#), flat: b (or <b); e.g. FA# or MIb. Each note uses the current OCTAVE/DURATION/TEMPO/TIMBRE. Interruptible with Ctrl+C.

PLAY "DO
PLAY [ DO RE MI FA SOL LA SI ]
PLAY [ DO RE# MI ]

Sets the octave of notes played by PLAY (1 to 5, default 4).

OCTAVE 4

Sets the note length (1 to 96, default 24).

DURATION 24

Sets the tempo (1 to 255, default 5): higher = faster.

TEMPO 5

Sets the timbre, i.e. the sound shape (0-63 square, 64-127 sawtooth, 128-191 triangle, 192-255 sine).

TIMBRE 0
TIMBRE 200

Sets the volume of notes played by PLAY (0 silent to 100 full, default 100).

VOLUME 100
VOLUME 30

Outputs the list of all known words (procedures and names).

PRINT CONTENTS
  -> .CHB .DEP .EXA .RES .ROUT .SER ABS ALLOPEN AND ANIMATE ARC ARCTAN ARRAY ARRAY? ARRAYP ARRAYTOLIST ASCII ASK BACK BACKGROUND BEFORE? BEFOREP BF BG BIN BK BL BUTFIRST BUTLAST BUTTON? BUTTONP BYE CAT CATALOG CATALOGEX CATCH CATEX CHAR CIRCLE CLEAN CLEARSCREEN CLEARTEXT CLEARTURTLES CLOSE CLOSEALL CLS COLLIDE? COLLIDEP CONTENTS COPIE COPY COPYARRAY COS COUNT CS DEFINE DEFSPRITE DELETE DEQUEUE DIFFERENCE DISTANCE DOT DRIVE DURATION EDIT EDLOAD EDLOADEX EDSAVE EMPTY? EMPTYP EN END ENGLISH ENTREE EOF? EOFP EOL EQUAL? EQUALP ER ERALL ERASE ERASEFILE ERN ERNAME EVALUATE EXP EXPAND FACTOR FALSE FD FENCE FILETOARRAY FILL FILTER FIRST FLI FLOODCOLOR FOR FOREACH FORMAT FORWARD FPUT FRENCH FROMBASE GOODBYE GPROP GREATER? GREATERP HEADING HELP HEX HIDETURTLE HOME HT IF IFELSE IFF IFFALSE IFT IFTRUE INSERTITEM INT INTQUOTIENT ITEM JOYSTICK KEY? KEYP LABEL LAST LEFT LESS? LESSP LIST LIST? LISTP LISTTOARRAY LN LOAD LOADEX LOCAL LOG10 LOWERCASE LPUT LT LTRIM MAKE MAP MDARRAY MDITEM MDSETITEM MEMBER MEMBER? MEMBERP MINUS MODULO MOUSEDOWN? MOUSEPOS NAME? NAMEP NODES NOT NUMBER? NUMBERP OCTAVE OP OPENAPPEND OPENREAD OPENUPDATE OPENWRITE OR OUTPUT PC PD PENCOLOR PENDOWN PENDOWN? PENDOWNP PENUP PI PICK PLAY PLIST PO POALL PONS POP POS POSITION POTS POWER PPROP PR PRIMITIVE? PRIMITIVEP PRINT PROCEDURE? PROCEDUREP PRODUCT PU PUSH QUEUE QUIT QUOTIENT RANDOM RCS READ READCHAR READCHARS READER READLIST READPOS READRAWLINE READWORD RECYCLE REDUCE REGLE REMAINDER REMDUP REMOVE REMPROP REPCOUNT REPEAT REPLACE RESET REVERSE RIGHT RL ROUND RT RTRIM RUN RUNRESULT RW SAVE SAVEPNG SCALE SCENE SE SENTENCE SETBACKGROUND SETBG SETBORDER SETCURSOR SETDRIVE SETEOL SETFC SETFLOODCOLOR SETFPS SETH SETHEADING SETITEM SETPC SETPENCOLOR SETPENSIZE SETPOS SETREAD SETREADPOS SETSCALE SETTEXTBACKGROUND SETTEXTCOLOR SETTEXTLINES SETTURTLE SETWRITE SETWRITEPOS SETXY SHOW SHOWN? SHOWNP SHOWTURTLE SIN SLICE SOLVE SORT SORTARRAY SORTIE SPLIT SPRITE SQRT ST STOP STOPALL STOPANIMATE SUBSTITUTE SUBSTRING? SUBSTRINGP SUM TAN TEMPO TEST TEXT THING THROW TIMBRE TO TOBASE TOPLEVEL TOWARDS TRIM TRUE TRUNCATE TURTLE TURTLES TYPE UPPERCASE VOLUME WAIT WHILE WINDOW WORD WORD? WORDP WRAP WRITEPOS WRITER XCOR XOR YCOR

Prints out the definition of the procedure named word.

PO "CARRE

Prints out the titles (TO line) of all procedures.

POTS

Prints out all names and their things, as MAKE statements.

PONS

Prints out all procedures (full definitions) then all names.

POALL

Erases the procedure named word.

ERASE "CARRE

Erases the name (variable) word.

ERNAME "AGE

Erases the whole workspace: all procedures and all names.

ERALL

Outputs the number of free memory cells.

PRINT NODES
  -> 60000

Reclaims unused memory (no effect: Go manages memory).

RECYCLE

Saves to file word the procedures and variables given by list (bare names = procedures, "name = variables, :name = list of names; CONTENTS = everything).

SAVE "DESSIN CONTENTS

Re-reads file word and DEFINES its contents directly IN THE WORKSPACE: its procedures and variables become usable at once (each procedure prints "X DEFINED"). Nothing else to do. --- Difference with EDLOAD: LOAD defines right away (to USE a program), whereas EDLOAD only puts the file in the editor without running it (to REWORK it).

LOAD "DESSIN

Loads file word INTO THE EDITOR, WITHOUT running it: its text becomes the editor content (ED with no argument reopens it). You must open ED then validate with Ctrl+S to run it. --- Difference with LOAD: EDLOAD is to READ or EDIT a program before validating it, whereas LOAD defines its contents directly in the workspace (usable right away).

EDLOAD "DESSIN

Saves the current editor content to file word.

EDSAVE "DESSIN

Lists the files in the working directory (name and size).

CATALOG

Permanently deletes file word. Refuses to delete an open file.

ERASEFILE "DESSIN

Lists the example files (name and size), like CATALOG but in the examples directory shipped with GoLogo. Error if there is no examples directory.

CATALOGEX

Like LOAD, but reads the file from the examples directory: re-reads it and DEFINES its contents in the workspace (usable at once). Error if the examples directory or the file is missing or unreadable.

LOADEX "DESSIN

Like EDLOAD, but reads the file from the examples directory: puts its text in the editor WITHOUT running it (EDIT reopens it, validate with Ctrl+S). Error if the examples directory or the file is missing or unreadable.

EDLOADEX "DESSIN

Saves the drawing (graphics field) to word.PNG, in the working folder (like SAVE). Asks for confirmation if the file exists.

SAVEPNG "DESSIN

"Prints" the screen: saves a numbered PNG screenshot (PAGE_1.PNG, PAGE_2.PNG...) in the PRINTER subfolder of the work directory.

COPIE

Formatted a floppy disk (period hardware). No effect here.

FORMAT 0

Returned the current disk drive. Not applicable here (outputs 1).

PRINT DRIVE
  -> 1

Selected the disk drive. No effect here.

SETDRIVE 0

Opens the file for reading (position at the start). Error if the file is missing or already open. From FMSLogo.

OPENREAD "DESSIN.GLG CLOSE "DESSIN.GLG

Opens the file for writing, overwriting any existing content WITHOUT asking (FMSLogo fidelity). Creates it if absent. From FMSLogo.

OPENWRITE "SORTIE.TXT CLOSE "SORTIE.TXT

Opens the file for writing, position at the end (append). Creates it if absent. From FMSLogo.

OPENAPPEND "JOURNAL.TXT CLOSE "JOURNAL.TXT

Opens the file for reading AND writing (a single, shared position). Creates it if absent. From FMSLogo.

OPENUPDATE "DESSIN.GLG CLOSE "DESSIN.GLG

Closes the file. If it was the current read/write stream, we revert to keyboard/console. Error if the file is not open. From FMSLogo.

OPENREAD "DESSIN.GLG CLOSE "DESSIN.GLG

Closes all open files. From FMSLogo.

OPENREAD "DESSIN.GLG CLOSEALL

Outputs the list of names of currently open files. From FMSLogo.

SHOW ALLOPEN
  -> []

Sets the current read stream: READCHAR/READWORD/READLIST/READRAWLINE will read from this file. An empty list [ ] reverts to the keyboard. Error if the file is not open for reading. From FMSLogo.

OPENREAD "DESSIN.GLG SETREAD "DESSIN.GLG SETREAD [ ] CLOSE "DESSIN.GLG

Sets the current write stream: PRINT/SHOW/TYPE will write to this file. An empty list [ ] reverts to the console. Error if the file is not open for writing. From FMSLogo.

OPENWRITE "SORTIE.TXT SETWRITE "SORTIE.TXT SETWRITE [ ] CLOSE "SORTIE.TXT

Outputs the name of the current read stream, or [ ] if it is the keyboard. From FMSLogo.

SHOW READER
  -> []

Outputs the name of the current write stream, or [ ] if it is the console. From FMSLogo.

SHOW WRITER
  -> []

Outputs TRUE if there is nothing left to read in the current read stream. On the keyboard, always FALSE. From FMSLogo.

PRINT EOF?
  -> FAUX

Outputs the current read byte position, or -1 if the stream is the keyboard. From FMSLogo.

PRINT READPOS
  -> -1

Outputs the current write byte position, or -1 if the stream is the console. From FMSLogo.

PRINT WRITEPOS
  -> -1

Moves the current read pointer to byte position (0-based). Error if the position is out of file or in the middle of a character. From FMSLogo.

OPENREAD "DESSIN.GLG SETREAD "DESSIN.GLG SETREADPOS 0 CLOSE "DESSIN.GLG

Moves the current write pointer to byte position (0-based). From FMSLogo.

OPENWRITE "SORTIE.TXT SETWRITE "SORTIE.TXT SETWRITEPOS 0 CLOSE "SORTIE.TXT

Reads a raw line from the current read stream and outputs it as a single word (no interpretation). This is THE receiver to walk a file line by line. [ ] at end of file. From FMSLogo.

OPENREAD "DESSIN.GLG SETREAD "DESSIN.GLG PRINT READRAWLINE SETREAD [ ] CLOSE "DESSIN.GLG

Reads n characters from the current read stream and outputs them as a word. [ ] at end of file. From FMSLogo.

OPENREAD "DESSIN.GLG SETREAD "DESSIN.GLG PRINT READCHARS 4 SETREAD [ ] CLOSE "DESSIN.GLG

Loads a whole text file at once and outputs an array whose cells are its lines (first line in cell 1). COUNT gives the number of lines, for easy iteration. Opens, reads and closes the file on its own. Refuses a binary file (BINARY FILE). gologo extension.

SHOW FILETOARRAY "DESSIN.GLG
MAKE "L FILETOARRAY "DESSIN.GLG PRINT COUNT :L

Sets the line ending written to files: "LF (default, Unix-style) or "CRLF (Windows-style). Reading always accepts both. gologo extension.

SETEOL "CRLF

Outputs the current line-ending setting: "LF or "CRLF. gologo extension.

PRINT EOL
  -> LF

Original light pen. Compatibility: no effect.

REGLE

Selected the input channel. Compatibility: no effect.

ENTREE 1

Selected the output channel (console, printer...). Compatibility: no effect.

SORTIE 2

Original line fill. Compatibility: no effect.

FLI 1

Serial port (absent on the original). Compatibility: no effect.

.SER 1 2

Binary load into memory. Compatibility: no effect.

.CHB "PROG 0

Reserved memory. Compatibility: no effect.

.RES 0

Stored a byte in memory. Compatibility: no effect.

.DEP 100 0

Ran a machine-code routine. Compatibility: no effect.

.ROUT 100

Read a byte in memory. Compatibility: always outputs 0.

PRINT .EXA 0
  -> 0

Without argument, lists all commands. With a name (e.g. HELP FORWARD), shows its description, parameters and aliases.

HELP REPEAT

Switches help and messages to French. Alias: FR.

FRENCH

Switches help and messages to English. English aliases: ENGLISH, EN.

ENGLISH

Quits GoLogo.

BYE